Script of gnuplot splot 3D animation graph

set xyplane at -1.5
set view 70, 125
set grid lw 2
unset key

i=10
iy_min=-10
y_min=-10
y_max=20
while (i<200){
splot [-2:2][y_min:y_max][-1.5:1.5] sample \
                               [a=iy_min:i:0.2] '+' using (cos(a)):(a):(sin(a)) lt 5 lc rgb 'purple' lw 3,\
                               [a=iy_min:i:0.1] '' using (cos(a)):(y_min):(sin(a)) w l lw 2, \
                               [a=iy_min:i:0.1] '' using (-2):(a):(sin(a)) w l lw 2, \
                               [a=iy_min:i:0.1] '' using (cos(a)):(a):(-1.5) w l lw 2, \
                               [c=iy_min:i] '' using (cos(i)):(c):(sin(i)) w l lc rgb 'dark-green',\
                               [e=-2:cos(i)] '' using (e):(i):(sin(i)) w l lc rgb 'dark-blue',\
                               [f=-1.5:sin(i)] '' using (cos(i)):(i):(f) w l lc rgb 'dark-orange'
#                               [e=-2:1] '' using (e):(0):(0) w l lc rgb 'dark-red',\
#                               [f=-10:0] '' using (1):(f):(0) w l lc rgb 'dark-red'
i=i+0.098
y_min=y_min+0.1
y_max=y_max+0.1
pause 0.01
}

pause -1